8.3 Reading and Writing Racket Data

As noted throughout Built-In Datatypes, Racket provides three ways to print an instance of a built-in value:

• print, which prints a value in the same way that is it printed for a REPL result; and

• write, which prints a value in such a way that read on the output produces the value back; and

• display, which tends to reduce a value to just its character or byte content—at least for those datatypes that are primarily about characters or bytes, otherwise it falls back to the same output as write.

Here are some examples using each:

> (print 1/2)   1/2   > (print #\x)   #\x   > (print "hello")   "hello"   > (print #"goodbye")   #"goodbye"   > (print '|pea pod|)   '|pea pod|   > (print '("i" pod))   '("i" pod)   > (print write)   #<procedure:write>

> (write 1/2)   1/2   > (write #\x)   #\x   > (write "hello")   "hello"   > (write #"goodbye")   #"goodbye"   > (write '|pea pod|)   |pea pod|   > (write '("i" pod))   ("i" pod)   > (write write)   #<procedure:write>

> (display 1/2)   1/2   > (display #\x)   x   > (display "hello")   hello   > (display #"goodbye")   goodbye   > (display '|pea pod|)   pea pod   > (display '("i" pod))   (i pod)   > (display write)   #<procedure:write>

Overall, print as corresponds to the expression layer of Racket syntax, write corresponds to the reader layer, and display roughly corresponds to the character layer.

The printf function supports simple formatting of data and text. In the format string supplied to printf, ~a displays the next argument, ~s writes the next argument, and ~v prints the next argument.

Examples:

(define (deliver who when what)     (printf "Items ~a for shopper ~s: ~v" who when what))

> (deliver '("list") '("John") '("milk"))

Items (list) for shopper ("John"): '("milk")

After using write, as opposed to display or print, many forms of data can be read back in using read. The same values printed can also be parsed by read, but the result may have extra quote forms, since a printed form is meant to be read like an expression.

Examples:

> (define-values (in out) (make-pipe))

> (write "hello" out)

> (read in)

"hello"

> (write '("alphabet" soup) out)

> (read in)

'("alphabet" soup)

> (write #hash((a . "apple") (b . "banana")) out)

> (read in)

'#hash((b . "banana") (a . "apple"))

> (write '("alphabet" soup) out)

> (read in)

'("alphabet" soup)